# Eelco Mossel, March 2008.
#
# First argument: file name of the input file; the input file is read as UTF-8.
# Output is written to STDOUT, also as UTF-8.
#
# This script generates a reduced/simplified version of the LT4eL lexicons, retaining all information
# that is used by the LT4eL services and by the ontology navigation feature in ILIAS.
#
# For each <entry> element, only the first <owl> or <rdf> element within an entry is preserved.
# The children are removed from it. All following elements up to (not including) the first <def>
# element are removed as well.
# Starting from the first <def> element, the rest of the entry is left unchanged.
#
# The script does not parse XML; rather, it assumes a certain layout,
# with respect to line breaks and order of elements:
# If the <def> or <termg> element are on the same line as the first <owl> or <rdf> element,
# they will be missing from the output.
#
# Input elements, example:
#    <entry id="upen-1">
#        <owl:Class rdf:about="http://www.loa-cnr.it/ontologies/DUL.owl#Abstract"><owl:disjointWith>
#                <owl:Class rdf:about="http://www.loa-cnr.it/ontologies/DUL.owl#Event"></owl:Class></owl:disjointWith><owl:disjointWith>
#                <owl:Class rdf:about="http://www.loa-cnr.it/ontologies/DUL.owl#Quality"></owl:Class></owl:disjointWith><owl:disjointWith>
#                <owl:Class rdf:about="http://www.loa-cnr.it/ontologies/DUL.owl#Object"></owl:Class></owl:disjointWith>
#            <rdfs:comment>Any Entity that cannot be located in space-time. E.g. mathematical entities: formal semantics elements, regions within dimensional spaces, etc.</rdfs:comment><rdfs:label xml:lang="it">Astratto</rdfs:label>
#            <rdfs:subClassOf>
#                <owl:Class rdf:about="http://www.loa-cnr.it/ontologies/DUL.owl#Entity"></owl:Class></rdfs:subClassOf></owl:Class>
#        <def>Any Entity that cannot be located in space-time. E.g. mathematical entities: formal semantics elements, regions within dimensional spaces, etc.</def>
#        <termg lang="de">
#            <term shead="1">Entwurf</term>
#            <term>Abstrakte</term>
#            <def></def>
#        </termg>
#    </entry>
#
# Output for this example:
#    <entry id="upen-1">
#        <owl:Class rdf:about="http://www.loa-cnr.it/ontologies/DUL.owl#Abstract"></owl:Class>
#        <def>Any Entity that cannot be located in space-time. E.g. mathematical entities: formal semantics elements, regions within dimensional spaces, etc.</def>
#        <termg lang="de">
#            <term shead="1">Entwurf</term>
#            <term>Abstrakte</term>
#            <def></def>
#        </termg>
#    </entry>

use strict;
use warnings;

open(LEX, $ARGV[0]);
binmode(LEX, ':utf8');
binmode(STDOUT, ':utf8');

my $doWrite = 1;
my $writeMainEntryElement = 0;
my $line = <LEX>;
while ($line) {
  if ($line =~ /(\s*<entry.*?>)(\s*<((owl|rdf):[^ ]+?) .*?>)/) { # entry + first owl/rdf element on one line
    print "$1\n        $2</$3>\n";
    $doWrite = 0; # do not write next lines, unless it contains <def> or <termg
  }
  elsif ($writeMainEntryElement) {
    $line =~ /(\s*<(owl:[^ ]+?) .*?>)/; print "$1</$2>\n";
    $doWrite = 0;
    $writeMainEntryElement = 0;
  }
  elsif ($line =~ /(\s*<entry.*?>)/ ) {
    print "$1\n";
    $writeMainEntryElement = 1;
  }
  elsif ($doWrite) {
    print $line;
  }
  elsif ($line =~ /<def>/ || $line =~ /<termg/) {
    print $line; $doWrite = 1;
  }
  $line = <LEX>;
}